首页 > 代码库 > Shell文本处理三剑客（三）
Shell文本处理三剑客（三）
防伪码：锄禾日当午，汗滴禾下土。
8.3.7 7 内置函数
函数 描述
int(expr) 截断为整数
sqrt(expr) 平方根
rand() 返回一个随机数 N，0 和 1 范围，0 < N < 1
srand([expr])
使用 expr 生成随机数，如果不指定，默认使用当前时间为种子，如
果前面有种子则使用生成随机数
asort(a, b)
对数组 a 的值进行排序，把排序后的值存到新的数组 b 中，新排序
的数组下标从 1 开始
asorti(a,b) 对数组 a 的下标进行排序，同上
sub(r, s [, t])
对输入的记录用 s 替换 r，t 可选针对某字段替换 ，但只替换第一
个字符串
gsub(r,s [, t]) 对输入的记录用 s 替换 r，t 可选针对某字段替换，替换所有字符串
index(s, t) 返回 s 中字符串 t 的索引位置，0 为不存在
length([s]) 返回 s 的长度
match(s, r [, a]) 测试字符串 s 是否包含匹配 r 的字符串
split(s, a [, r [,
seps] ])
根据分隔符 seps 将 s 分成数组 a
substr(s, i [, n]) 截取字符串 s 从 i 开始到长度 n，如果 n 没指定则是剩余部分
tolower(str) str 中的所有大写转换成小写
toupper(str) str 中的所有小写转换成大写
systime() 当前时间戳
strftime([format [,
timestamp[, utc-
flag]]])
格式化输出时间，将时间戳转为字符串
示例：
1）int()
# echo "123abc abc123 123abc123" |xargs -n1 | awk ‘{print int($0)}‘
123
0
123
# awk ‘BEGIN{print int(10/3)}‘
3
2）sqrt()
获取 9 的平方根：
# awk ‘BEGIN{print sqrt(9)}‘
3
3）rand()和 srand()
rand()并不是每次运行就是一个随机数，会一直保持一个不变：
# awk ‘BEGIN{print rand()}‘
0.237788
当执行 srand()函数后，rand()才会发生变化，所以一般在 awk 着两个函数结合生成随机数，但是
也有很大几率生成一样：
# awk ‘BEGIN{srand();print rand()}‘
0.31687
如果想生成 1-10 的随机数可以这样：
# awk ‘BEGIN{srand();print int(rand()*10)}‘
4
如果想更完美生成随机数，还得做相应的处理！
4）asort()和 asorti()
# seq -f "str%.g" 5 |awk ‘{a[x++]=$0}END{s=asort(a,b);for(i=1;i<=s;i++)print
b[i],i}‘
str1 1
str2 2
str3 3
str4 4
str5 5
# seq -f "str%.g" 5 |awk ‘{a[x++]=$0}END{s=asorti(a,b);for(i=1;i<=s;i++)print
b[i],i}‘
0 1
1 2
2 3
3 4
4 5
asort 将 a 数组的值放到数组 b，a 下标丢弃，并将数组 b 的总行号赋值给 s，新数组 b 下标从 1 开
始，然后遍历。
5）sub()和 gsub()
# tail /etc/services |awk ‘/blp5/{sub(/tcp/,"icmp");print $0}‘
blp5 48129/icmp # Bloomberg locator
blp5 48129/udp # Bloomberg locator
# tail /etc/services |awk ‘/blp5/{gsub(/c/,"9");print $0}‘
blp5 48129/t9p # Bloomberg lo9ator
blp5 48129/udp # Bloomberg lo9ator
# echo "1 2 2 3 4 5" |awk ‘gsub(2,7,$2){print $0}‘
1 7 2 3 4 5
# echo "1 2 3 a b c" |awk ‘gsub(/[0-9]/, ‘0‘){print $0}‘
0 0 0 a b c
在指定行前后加一行：
# seq 5 | awk ‘NR==2{sub(‘/.*/‘,"txt\n&")}{print}‘
1
txt
2
3
4
5
# seq 5 | awk ‘NR==2{sub(‘/.*/‘,"&\ntxt")}{print}‘
1
2
txt
3
4
5
6）index()
# tail -n 5 /etc/services |awk ‘{print index($2,"tcp")}‘
7
0
7
0
7
7）length()
# tail -n 5 /etc/services |awk ‘{print length($2)}‘
9
9
9
9
9
统计数组的长度：
# tail -n 5 /etc/services |awk ‘{a[$1]=$2}END{print length(a)}‘
3
8）split()
# echo -e "123#456#789\nabc#cde#fgh" |awk ‘{split($0,a);for(v in a)print a[v],v}‘
123#456#789 1
abc#cde#fgh 1
# echo -e "123#456#789\nabc#cde#fgh" |awk ‘{split($0,a,"#");for(v in a)print a[v],v}‘
123 1
456 2
789 3
abc 1
cde 2
fgh 3
9）substr()
# echo -e "123#456#789\nabc#cde#fgh" |awk ‘{print
substr($0,4)}‘
#456#789
#cde#fgh
# echo -e "123#456#789\nabc#cde#fgh" |awk ‘{print substr($0,4,5)}‘
#456#
#cde#
10）tolower()和 toupper()
# echo -e "123#456#789\nABC#cde#fgh" |awk ‘{print tolower($0)}‘
123#456#789
abc#cde#fgh
# echo -e "123#456#789\nabc#cde#fgh" |awk ‘{print toupper($0)}‘
123#456#789
ABC#CDE#FGH
11)时间处理
返回当前时间戳：
# awk ‘BEGIN{print systime()}‘
1483297766
将时间戳转为日期和时间
# echo "1483297766" |awk ‘{print strftime("%Y-%m-%d %H:%M:%S",$0)}‘
2017-01-01 14:09:26
8.3.8 8 O I/O 语句
语句 描述
getline 读取下一个输入记录设置给$0
getline var 读取下一个输入记录并赋值给变量 var
command | getline [var] 运行 Shell 命令管道输出到$0 或 var
next 停止当前处理的输入记录后面动作
print 打印当前记录
printf fmt, expr-list 格式化输出
printf fmt, expr-list >file 格式输出和写到文件
system(cmd-line) 执行命令和返回状态
print ... >> file 追加输出到文件
print ... | command 打印输出作为命令输入
示例：
1）getline
获取匹配的下一行：
# seq 5 |awk ‘/3/{getline;print}‘
4
# seq 5 |awk ‘/3/{print;getline;print}‘
3
4
在匹配的下一行加个星号：
# seq 5 |awk ‘/3/{getline;sub(".*","&*");print}‘
4*
# seq 5 |awk ‘/3/{print;getline;sub(".*","&*")}{print}‘
1
2
3
4*
5
2）getline var
把 a 文件的行追加到 b 文件的行尾：
# cat a
a
b
c
# cat b
1 one
2 two
3 three
# awk ‘{getline line<"a";print $0,line}‘ b
1 one a
2 two b
3 three c
把 a 文件的行替换 b 文件的指定字段：
# awk ‘{getline line<"a";gsub($2,line,$2);print}‘ b
1 a
2 b
3 c
把 a 文件的行替换 b 文件的对应字段：
# awk ‘{getline line<"a";gsub("two",line,$2);print}‘ b
1 one
2 b
3 three
3）command | getline [var]
获取执行 shell 命令后结果的第一行：
# awk ‘BEGIN{"seq 5"|getline var;print var}‘
1
循环输出执行 shell 命令后的结果：
# awk ‘BEGIN{while("seq 5"|getline)print}‘
1
2
3
4
5
4）next
不打印匹配行：
# seq 5 |awk ‘{if($0==3){next}else{print}}‘
1
2
4
5
删除指定行：
# seq 5 |awk ‘NR==1{next}{print $0}‘
2
3
4
5
如果前面动作成功，就遇到 next，后面的动作不再执行，跳过。
或者：
# seq 5 |awk ‘NR!=1{print}‘
2
3
4
5
把第一行内容放到每行的前面：
# cat a
hello
1 a
2 b
3 c
# awk ‘NR==1{s=$0;next}{print s,$0}‘ a
hello 1 a
hello 2 b
hello 3 c
# awk ‘NR==1{s=$0}NF!=1{print s,$0}‘ a
hello 1 a
hello 2 b
hello 3 c
5）system()
执行 shell 命令判断返回值：
# awk ‘BEGIN{if(system("grep root /etc/passwd &>/dev/null")==0)print "yes";else print
"no"}‘
yes
6）打印结果写到文件
# tail -n5 /etc/services |awk ‘{print $2 > "a.txt"}‘
# cat a.txt
48049/tcp
48128/tcp
48128/udp
48129/tcp
48129/udp
7）管道连接 shell 命令
将结果通过 grep 命令过滤：
# tail -n5 /etc/services |awk ‘{print $2|"grep tcp"}‘
48556/tcp
48619/tcp
49000/tcp
8.3.9 9 f printf 语句
格式化输出，默认打印字符串不换行。
格式：printf [format] arguments
Format 描述
%s 一个字符串
%d，%i 一个小数
%f 一个浮点数
%.ns 输出字符串，n 是输出几个字符
%ni 输出整数，n 是输出几个数字
%m.nf 输出浮点数，m 是输出整数位数，n 是输出的小数位数
%x 不带正负号的十六进制，使用 a 至 f 表示 10 到 15
%X 不带正负号的十六进制，使用 A 至 F 表示 10 至 15
%% 输出单个%
%-5s 左对齐，对参数每个字段左对齐,宽度为 5
%-4.2f 左对齐，宽度为 4，保留两位小数
%5s 右对齐，不加横线表示右对齐
示例：
将换行符换成逗号：
# seq 5 |awk ‘{if($0!=5)printf "%s,",$0;else print $0}‘
1,2,3,4,5
小括号中的 5 是最后一个数字。
输出一个字符：
# awk ‘BEGIN{printf "%.1s\n","abc"}‘
a
保留一个小数点：
# awk ‘BEGIN{printf "%.2f\n",10/3}‘
3.33
格式化输出：
# awk ‘BEGIN{printf "user:%s\tpass:%d\n","abc",123}‘
user:abc pass:123
左对齐宽度 10：
# awk ‘BEGIN{printf "%-10s %-10s %-10s\n","ID","Name","Passwd"}‘
ID Name Passwd
右对齐宽度 10：
# awk ‘BEGIN{printf "%10s %10s %10s\n","ID","Name","Passwd"}‘
ID Name Passwd
打印表格：
# vi test.awk
BEGIN{
print "+--------------------+--------------------+";
printf "|%-20s|%-20s|\n","Name","Number";
print "+--------------------+--------------------+";
}
# awk -f test.awk
+--------------------+--------------------+
|Name |Number |
+--------------------+--------------------+
格式化输出：
# awk -F: ‘BEGIN{printf "UserName\t\tShell\n-----------------------------\n"}{printf
"%-20s %-20s\n",$1,$7}END{print "END...\n"}‘ /etc/passwd
打印十六进制：
# awk ‘BEGIN{printf "%x %X",123,123}‘
7b 7B
8.3. 10 自定义 函数
格式：function name(parameter list) { statements }
示例：
# awk ‘function myfunc(a,b){return a+b}BEGIN{print myfunc(1,2)}‘
3
8.3.11 1 需求案例
1）分析 Nginx 日志
日志格式：
‘$remote_addr - $remote_user [$time_local] "$request" $status $body_bytes_sent "
$http_referer" "$http_user_agent" "$http_x_forwarded_for"‘
统计访问 IP 次数：
# awk ‘{a[$1]++}END{for(v in a)print v,a[v]}‘ access.log
统计访问访问大于 100 次的 IP：
# awk ‘{a[$1]++}END{for(v in a){if(a[v]>100)print v,a[v]}}‘ access.log
统计访问 IP 次数并排序取前 10：
# awk ‘{a[$1]++}END{for(v in a)print v,a[v] |"sort -k2 -nr |head -10"}‘ access.log
统计时间段访问最多的 IP：
# awk ‘$4>="[02/Jan/2017:00:02:00" && $4<="[02/Jan/2017:00:03:00"{a[$1]++}END{for(v in
a)print v,a[v]}‘ access.log
统计上一分钟访问量：
# date=$(date -d ‘-1 minute‘ +%d/%d/%Y:%H:%M)
# awk -vdate=$date ‘$4~date{c++}END{print c}‘ access.log
统计访问最多的 10 个页面：
# awk ‘{a[$7]++}END{for(v in a)print v,a[v] |"sort -k1 -nr|head -
n10"}‘ access.log
统计每个 URL 数量和返回内容总大小：
# awk ‘{a[$7]++;size[$7]+=$10}END{for(v in a)print a[v],v,size[v]}‘ access.log
统计每个 IP 访问状态码数量：
# awk ‘{a[$1" "$9]++}END{for(v in a)print v,a[v]}‘ access.log
统计访问 IP 是 404 状态次数：
# awk ‘{if($9~/404/)a[$1" "$9]++}END{for(i in a)print v,a[v]}‘ access.log
2）两个文件对比
找出 b 文件在 a 文件相同记录：
# seq 1 5 > a
# seq 3 7 > b
方法 1：
# awk ‘FNR==NR{a[$0];next}{if($0 in a)print $0}‘ a b
3
4
5
# awk ‘FNR==NR{a[$0];next}{if($0 in a)print FILENAME,$0}‘ a b
b 3
b 4
b 5
# awk ‘FNR==NR{a[$0]}NR>FNR{if($0 in a)print $0}‘ a b
3
4
5
# awk ‘FNR==NR{a[$0]=1;next}(a[$0]==1)‘ a b # a[$0]是通过 b 文件每行获取值，如果是 1
说明有
# awk ‘FNR==NR{a[$0]=1;next}{if(a[$0]==1)print}‘ a b
3
4
5
方法 2：
# awk ‘FILENAME=="a"{a[$0]}FILENAME=="b"{if($0 in a)print $0}‘ a b
3
4
5
方法 3：
# awk ‘ARGIND==1{a[$0]=1}ARGIND==2 && a[$0]==1‘ a b
3
4
5
找出 b 文件在 a 文件不同记录：
方法 1：
# awk ‘FNR==NR{a[$0];next}!($0 in a)‘ a b
6
7
# awk ‘FNR==NR{a[$0]=1;next}(a[$0]!=1)‘ a b
# awk ‘FNR==NR{a[$0]=1;next}{if(a[$0]!=1)print}‘ a b
6
7
方法 2：
# awk ‘FILENAME=="a"{a[$0]=1}FILENAME=="b" && a[$0]!=1‘ a b
方法 3：
# awk ‘ARGIND==1{a[$0]=1}ARGIND==2 && a[$0]!=1‘ a b
3）合并两个文件
将 a 文件合并到 b 文件：
# cat a
zhangsan 20
lisi 23
wangwu 29
# cat b
zhangsan man
lisi woman
wangwu man
# awk ‘FNR==NR{a[$1]=$0;next}{print a[$1],$2}‘ a b
zhangsan 20 man
lisi 23 woman
wangwu 29 man
# awk ‘FNR==NR{a[$1]=$0}NR>FNR{print a[$1],$2}‘ a b
zhangsan 20 man
lisi 23 woman
wangwu 29 man
将 a 文件相同 IP 的服务名合并：
# cat a
192.168.1.1: httpd
192.168.1.1: tomcat
192.168.1.2: httpd
192.168.1.2: postfix
192.168.1.3: mysqld
192.168.1.4: httpd
# awk ‘BEGIN{FS=":";OFS=":"}{a[$1]=a[$1] $2}END{for(v in a)print v,a[v]}‘ a
192.168.1.4: httpd
192.168.1.1: httpd tomcat
192.168.1.2: httpd postfix
192.168.1.3: mysqld
说明：数组 a 存储是$1=a[$1] $2，第一个 a[$1]是以第一个字段为下标，值是 a[$1] $2，也就是
$1=a[$1] $2，值的 a[$1]是用第一个字段为下标获取对应的值，但第一次数组 a 还没有元素，那么
a[$1]是空值，此时数组存储是 192.168.1.1=httpd，再遇到 192.168.1.1 时，a[$1]通过第一字段
下标获得上次数组的 httpd，把当前处理的行第二个字段放到上一次同下标的值后面，作为下标
192.168.1.1 的新值。此时数组存储是 192.168.1.1=httpd tomcat。每次遇到相同的下标（第一个
字段）就会获取上次这个下标对应的值与当前字段并作为此下标的新值。
4）将第一列合并到一行
# cat file
1 2 3
4 5 6
7 8 9
# awk ‘{for(i=1;i<=NF;i++)a[i]=a[i]$i" "}END{for(v in a)print a[v]}‘ file
1 4 7
2 5 8
3 6 9
说明：
for 循环是遍历每行的字段，NF 等于 3，循环 3 次。
读取第一行时：
第一个字段：a[1]=a[1]1" " 值 a[1]还未定义数组，下标也获取不到对应的值，所以为空，因此
a[1]=1 。
第二个字段：a[2]=a[2]2" " 值 a[2]数组 a 已经定义，但没有 2 这个下标，也获取不到对应的
值，为空，因此 a[2]=2 。
第三个字段：a[3]=a[3]3" " 值 a[2]与上面一样，为空,a[3]=3 。
读取第二行时：
第一个字段：a[1]=a[1]4" " 值 a[2]获取数组 a 的 2 为下标对应的值，上面已经有这个下标了，
对应的值是 1，因此 a[1]=1 4
第二个字段：a[2]=a[2]5" " 同上，a[2]=2 5
第三个字段：a[3]=a[3]6" " 同上，a[2]=3 6
读取第三行时处理方式同上，数组最后还是三个下标，分别是 1=1 4 7，2=2 5 8，3=3 6 9。最后
for 循环输出所有下标值。
5）字符串拆分，统计出现的次数
字符串拆分：
方法 1：
# echo "hello world" |awk -F ‘‘ ‘{print $1}‘
h
# echo "hello" |awk -F ‘‘ ‘{for(i=1;i<=NF;i++)print $i}‘
h
e
l
l
o
方法 2：
# echo "hello" |awk ‘{split($0,a,"‘‘");for(v in a)print a[v]}‘
l
o
h
e
l
统计字符串中每个字母出现的次数：
# echo "a.b.c,c.d.e" |awk -F ‘[.,]‘ ‘{for(i=1;i<=NF;i++)a[$i]++}END{for(v in a)print
v,a[v]}‘
a 1
b 1
c 2
d 1
e 1
5）费用统计
# cat a
zhangsan 8000 1
zhangsan 5000 1
lisi 1000 1
lisi 2000 1
wangwu 1500 1
zhaoliu 6000 1
zhaoliu 2000 1
zhaoliu 3000 1
# awk ‘{name[$1]++;cost[$1]+=$2;number[$1]+=$3}END{for(v in name)print
v,cost[v],number[v]}‘ a
zhangsan 5000 1
lisi 3000 2
wangwu 1500 1
zhaoliu 11000 3
6）获取数字字段最大值
# cat a
a b 1
c d 2
e f 3
g h 3
i j 2
获取第三字段最大值：
# awk ‘BEGIN{max=0}{if($3>max)max=$3}END{print max}‘ a
3
打印第三字段最大行：
# awk ‘BEGIN{max=0}{a[$0]=$3;if($3>max)max=$3}END{for(v in a)print v,a[v],max}‘ a
g h 3 3 3
e f 3 3 3
c d 2 2 3
a b 1 1 3
i j 2 2 3
# awk ‘BEGIN{max=0}{a[$0]=$3;if($3>max)max=$3}END{for(v in a)if(a[v]==max)print v}‘ a
g h 3
e f 3
7）去除第一行和最后一行
# seq 5 |awk ‘NR>2{print s}{s=$0}‘
2
3
4
读取第一行，NR=1，不执行 print s，s=1
读取第二行，NR=2，不执行 print s，s=2 （大于为真）
读取第三行，NR=3，执行 print s，此时 s 是上一次 p 赋值内容 2，s=3
最后一行，执行 print s，打印倒数第二行，s=最后一行
获取 Nginx 负载均衡配置端 IP 和端口：
# cat nginx.conf
upstream example-servers1 {
server 127.0.0.1:80 weight=1 max_fails=2 fail_timeout=30s;
}
upstream example-servers2 {
server 127.0.0.1:80 weight=1 max_fails=2 fail_timeout=30s;
server 127.0.0.1:82 backup;
}
# awk ‘/example-servers1/,/}/{if(NR>2){print s}{s=$2}}‘ nginx.conf
127.0.0.1:80
# awk ‘/example-servers1/,/}/{if(i>1)print s;s=$2;i++}‘ nginx.conf
# awk ‘/example-servers1/,/}/{if(i>1){print s}{s=$2;i++}}‘ nginx.conf
127.0.0.1:80
读取第一行，i 初始值为 0，0>1 为假，不执行 print s，x=example-servers1，i=1
读取第二行，i=1，1>1 为假，不执行 print s，s=127.0.0.1:80,i=2
读取第三行，i=2，2>1 为真，执行 print s，此时 s 是上一次 s 赋值内容 127.0.0.1:80，i=3
最后一行，执行 print s，打印倒数第二行，s=最后一行。
这种方式与上面一样，只是用 i++作为计数器。
8）知道上述方式，就可以实现这种需求了，打印匹配行的上一行
# seq 5 |awk ‘/3/{print s}{s=$0}‘
2
谢谢观看，真心的希望能帮到您！
本文出自 “一盏烛光” 博客，谢绝转载！
Shell文本处理三剑客（三）