网上查了很多，但是执行都各种错误，然后自己研究了半天，整了个能用的

要求：FTP文件名中含日期

步骤：将一下代码保存为BAT脚本，配置定时任务即可

@echo off
rem 计算指定天数之前的日期
set DaysAgo=1
rem 假设系统日期的格式为yyyy-mm-dd
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%%DstMonth%%DstDay%
echo %DaysAgo%天的日期是%DstDate%
echo %DstDate%  /*计算指定天数之前日期*/

rem 指定FTP用户名
set ftpUser=ftpadmin
rem 指定FTP密码
set ftpPass=123456
rem 指定FTP服务器地址
set ftpIP=172.19.13.13
rem 指定待下载的文件位于FTP服务器的哪个目录
set ftpFolder=/
rem 指定从FTP下载下来的文件存放到本机哪个目录
set LocalFolder=e:/ftp
 
set ftpFile=%temp%/TempFTP.txt
>"%ftpFile%" (
  echo,%ftpUser%
  echo,%ftpPass%
  echo cd "%ftpFolder%"
  echo lcd "%LocalFolder%"
  echo bin
  echo mget *%DstDate%*.*
  echo bye
)
start ftp -v -i -s:"%ftpFile%" %ftpIP%

goto :eof
:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF
:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

本文出自 “湖南土特产代购” 博客，请务必保留此出处http://zhsoft.blog.51cto.com/8345220/1907133

ftp下载指定日期文件（文件名中含日期）