首页 > 代码库 > 使用vbs脚本进行批量编码转换
使用vbs脚本进行批量编码转换
使用vbs脚本进行批量编码转换
最近需要使用SourceInsight查看分析在Linux系统下开发的项目代码，我们知道Linux系统中文本文件默认编码格式是UTF-8，而Windows中文系统中的默认编码格式是Gb2312。系统内的编码格式有所区别倒无伤大雅，关键的是SourceInsight竟不支持UTF-8，导致项目代码内的中文注释全部乱码！
既然SourceInsight不支持UTF-8编码的文件，那我们就得想办法将UTF-8的代码文件转化为GB2312编码的。首先想到的是到网上搜一下“批量编码转换工具”，结果下载后发现编码转换后的文件总是出现乱码，可能是工具的bug吧。既然不能使用工具转换，那就自己写一个程序进行编码转换，但是细想一下觉得C++/java的编码转换程序写起来又比较啰嗦，要是在Linux下写一个shell脚本就能轻松搞定了。还好Windows下有vbs脚本可以帮助我们轻松达到这个目的。
‘-------------------------------------------------
‘函数名称:ReadFile
‘作用:利用AdoDb.Stream对象来读取各种格式的文本文件
‘-------------------------------------------------
Function ReadFile(FileUrl, CharSet)
Dim Str
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.loadfromfile FileUrl
Str = stm.readtext
stm.Close
Set stm = Nothing
ReadFile = Str
End Function
我们使用ReadFile函数读取文件，其中FileUrl指定文件的路径，CharSet指定文件的原始编码格式，使用adodb.stream对象读取文件内容到Str。
‘-------------------------------------------------
‘函数名称:WriteToFile
‘作用:利用AdoDb.Stream对象来写入各种格式的文本文件
‘-------------------------------------------------
Function WriteToFile (FileUrl, Str, CharSet)
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.WriteText Str
stm.SaveToFile FileUrl, 2
stm.flush
stm.Close
Set stm = Nothing
End Function
然后使用WriteToFile将Str写回原文件FileUrl，并设定新的编码CharSet。
‘-------------------------------------------------
‘函数名称:ConvertFile
‘作用:将一个文件进行编码转换
‘-------------------------------------------------
Function ConvertFile(FileUrl)
Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)
End Function
这样ConvertFile对上述两个函数封装，实现文件FileUrl的编码转换，其中原始编码SrcCode与目的编码DestCode为全局变量。
如果仅对一个文件进行编码转换，我们不必这么大费周章。我们希望能对任意的文件或文件夹内的所有文件进行编码转换，达到批量转换的目的。
‘-------------------------------------------------
‘函数名称:ConvertDir
‘作用:将任意目录内的文件进行编码转换
‘-------------------------------------------------
Function ConvertDir(DirUrl)
If fs.FileExists(DirUrl) Then
Call ConvertFile(DirUrl)
Else
Call SearchDir(DirUrl)
End If
End Function
函数ConvertDir对任意路径的文件/文件夹进行编码转换，使用scripting.filesystemobject对象的FileExists函数判断路径对应的是文件还是文件夹，如果是文件则直接调用ConvertFile进行编码转换，否则调用SearchDir处理文件夹。
‘-------------------------------------------------
‘函数名称:SearchDir
‘作用:递归查找目录内的文件，进行编码转换
‘-------------------------------------------------
Function SearchDir(path)
Set folder = fs.getfolder(path)
Set subfolders = folder.subfolders
Set Files = folder.Files
For Each i In Files
Call ConvertFile(i.path)
Next
For Each j In subfolders
Call SearchDir(j.path)
Next
End Function
函数SearchDir是递归的，首先调用getfolder创建文件夹对象，然后取出文件夹内的子文件夹集合subfolders和子文件集合files。对于每个子文件，直接调用ConvertFile进行编码转换即可，而对于每个子文件夹，则递归调用SearchDir重复处理。
‘-------------------------------------------------
‘设置编码：默认 utf-8 --> gb2312
‘-------------------------------------------------
SrcCode="utf-8"
DestCode="gb2312"
‘-------------------------------------------------
‘解析参数
‘-------------------------------------------------
Set fs = CreateObject("scripting.filesystemobject")
Set objArgs = WScript.Arguments
If objArgs.Count>0 Then
For I = 0 To objArgs.Count - 1
FileUrl = objArgs(I)
Call ConvertDir(FileUrl)
Next
Else
MsgBox "没有文件/文件夹被拖入！"
wscript.quit
End If
MsgBox "转换成功！"
最后通过解析脚本文件的参数，由于每个参数对应一个文件/文件夹的路径，将之传递给ConvertDir即可。这里默认的是将UTF-8编码转化为GB2312编码，读者可以根据自身需要自行修改。
将上述代码保存为ConvertCode.vbs，只需要将任意多个文件选中拖动到该脚本文件上即可。或者使用命令行。
> ConvertCode.vbs [filepath]
需要注意的是文件编码是就地转换的，在转换之前最好将原文件/文件夹进行备份。
最后附上脚本文件的所有代码。
‘ * Intro 把要转换的多个文件/文件夹拖到该文件上即可
‘ * FileName ConvertCode.vbs
‘ * Author Florian
‘ * Version v1.0
‘ * WEB http://www.cnblogs.com/fanzhidongyzby
‘ * Email fanzhidongyzby@163.com
‘ * LastModify 2014-06-11 00:39:58
‘ *==========================================================*/
‘-------------------------------------------------
‘设置编码：默认 utf-8 --> gb2312
‘-------------------------------------------------
SrcCode="utf-8"
DestCode="gb2312"
‘-------------------------------------------------
‘解析参数
‘-------------------------------------------------
Set fs = CreateObject("scripting.filesystemobject")
Set objArgs = WScript.Arguments
If objArgs.Count>0 Then
For I = 0 To objArgs.Count - 1
FileUrl = objArgs(I)
Call ConvertDir(FileUrl)
Next
Else
MsgBox "没有文件/文件夹被拖入！"
wscript.quit
End If
MsgBox "转换成功！"
‘-------------------------------------------------
‘函数名称:ConvertDir
‘作用:将任意目录内的文件进行编码转换
‘-------------------------------------------------
Function ConvertDir(DirUrl)
If fs.FileExists(DirUrl) Then
Call ConvertFile(DirUrl)
Else
Call SearchDir(DirUrl)
End If
End Function
‘-------------------------------------------------
‘函数名称:SearchDir
‘作用:递归查找目录内的文件，进行编码转换
‘-------------------------------------------------
Function SearchDir(path)
Set folder = fs.getfolder(path)
Set subfolders = folder.subfolders
Set Files = folder.Files
For Each i In Files
Call ConvertFile(i.path)
Next
For Each j In subfolders
Call SearchDir(j.path)
Next
End Function
‘-------------------------------------------------
‘函数名称:ConvertFile
‘作用:将一个文件进行编码转换
‘-------------------------------------------------
Function ConvertFile(FileUrl)
Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)
End Function
‘-------------------------------------------------
‘函数名称:ReadFile
‘作用:利用AdoDb.Stream对象来读取各种格式的文本文件
‘-------------------------------------------------
Function ReadFile(FileUrl, CharSet)
Dim Str
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.loadfromfile FileUrl
Str = stm.readtext
stm.Close
Set stm = Nothing
ReadFile = Str
End Function
‘-------------------------------------------------
‘函数名称:WriteToFile
‘作用:利用AdoDb.Stream对象来写入各种格式的文本文件
‘-------------------------------------------------
Function WriteToFile (FileUrl, Str, CharSet)
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.WriteText Str
stm.SaveToFile FileUrl, 2
stm.flush
stm.Close
Set stm = Nothing
End Function