首页 > 代码库 > 顶点/片元 shader 总结

顶点/片元 shader 总结

2024-11-23 17:43:02   202人阅读

Cg顶点程序必须在结构中传递顶点数据。几种常用的顶点结构定义在文件UnityCG.cginc中，有如下三种结构体：

1、appdata_base： 包含顶点位置，法线和一个纹理坐标。
2、appdata_tan：包含顶点位置，切线，法线和一个纹理坐标。
3、appdata_full：包含位置、法线、切线、顶点色和两个纹理坐标。

struct appdata_base {
    float4 vertex : POSITION; //顶点坐标
    float3 normal : NORMAL;//法线
    float4 texcoord : TEXCOORD0;//UV
};
struct appdata_tan {

    float4 vertex : POSITION;
    float4 tangent : TANGENT;
    float3 normal : NORMAL;
    float4 texcoord : TEXCOORD0;
};
struct appdata_full {
    float4 vertex : POSITION;//顶点坐标
    float4 tangent : TANGENT;//正切
    float3 normal : NORMAL;//法线
    float4 texcoord : TEXCOORD0;//第一层UV
    float4 texcoord1 : TEXCOORD1; //第二层UV
    fixed4 color : COLOR; //颜色
};

注：顶点坐标和正切线为什么是float4，这有点意思，因为这里它表示是齐次坐标，比如我们这样表示一个float4（x,y,z,w），当w = 1的时候它表示点(x,y,z)，当w= 0的时候它表示一个向量(x,y,z)。区别就在这里，当W为1时表示点，当W为0时表示向量。

　　texcoord0和texcoord1分别表示两层UV，有时候我们模型上的贴图需要多个图片一起贴在一处，那么贴两层就会有两层UV。

　　以上三种类型为Unity内置的顶点Shader传入结构体，如果想自定义也是可以的，但是自定义结构体里面的属性，必须是基于appdata_full的，这样才能识别出来，也就是自定义的结构里的属性必须到appdata_full里的属性里去选。

下面给一个简单的顶点/片元 shader 事例：

Shader "Custom/Example" {
    Properties {
    _MainTex ("Texture", 2D) = "white" { }   //引号里面的"Texture"则是Unity检视面板中对应显示的属性名称
    }
    SubShader
    {
        pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            sampler2D _MainTex;
            //_MainTex_ST的ST应该是SamplerTexture的意思 ，就是声明_MainTex是一张采样图，也就是会进行UV运算。  
            //如果没有这句话，是不能进行TRANSFORM_TEX的运算的。_MainTex_ST.xy为 图中的Tiling,zw为图中的offset.
            float4 _MainTex_ST;

            struct v2f {
                float4  pos : SV_POSITION;
                float2  uv : TEXCOORD0;
            } ;

            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = mul(UNITY_MATRIX_MVP,v.vertex); //MVP矩阵变换，将裁剪空间坐标转换为相对屏幕位置的UV坐标
                o.uv = TRANSFORM_TEX(v.texcoord,_MainTex); //TRANSFORM_TEX的作用是用顶点的UV v.texcoord和材质球的采样图片_MainTex做运算，确保顶点材质球里的缩放和偏移是正确的。等价于o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
                return o;
            }

            float4 frag (v2f i) : COLOR
            {
                float4 texCol = tex2D(_MainTex,i.uv);
                float4 outp = texCol;
                return outp;
            }
            ENDCG
        }
    }
}

其中SV_POSITION，SV_前缀的变量代表system value，在DX10以后的语义绑定中被使用代表特殊的意义，和POSITION用法并无不同。唯一区别是 SV_POSTION一旦被作为vertex shader的输出语义，那么这个最终的顶点位置就被固定了(不能tensellate，不能再被后续改变它的空间位置？)，直接进入光栅化处理，如果作为fragment shader的输入语义那么和POSITION是一样的，代表着每个像素点在屏幕上的位置（这个说法其实并不准确，事实是fragment 在 view space空间中的位置，但直观的感受是如括号之前所述一般） 
最后这个回答者说了，在DX10版本之前没有引入SV_的预定义语义，POSITION被用作vertex shader的输入，输出，fragment shader的输入参数。但DX10之后就推荐使用SV_POSITION作为vertex shader的输出和fragment shader的输入了，注意vertex shader的输入还是使用POSITION！切记。但是DX10以后的代码依旧兼容POSITION作为全程表达，估计编译器会自动判断并替换的吧。

最后推荐两篇不错的博客，

https://onevcat.com/2013/07/shader-tutorial-1/

http://blog.csdn.net/ring0hx/article/details/46440037

顶点/片元 shader 总结


联系
我们