首页 > 代码库 > 合并果子问题浅析

合并果子问题浅析

2024-07-06 04:21:11   223人阅读

这是04年NOIP普及组的一道题，题目如下:

题目描述 Description

    在一个果园里，多多已经将所有的果子打了下来，而且按果子的不同种类分成了不同的堆。多多决定把所有的果子合成一堆。 每一次合并，多多可以把两堆果子合并到一起，消耗的体力等于两堆果子的重量之和。可以看出，所有的果子经过n-1次合并之后，就只剩下一堆了。多多在合并果子时总共消耗的体力等于每次合并所耗体力之和。 因为还要花大力气把这些果子搬回家，所以多多在合并果子时要尽可能地节省体力。假定每个果子重量都为1，并且已知果子的种类数和每种果子的数目，你的任务是设计出合并的次序方案，使多多耗费的体力最少，并输出这个最小的体力耗费值。 例如有3种果子，数目依次为1，2，9。可以先将1、2堆合并，新堆数目为3，耗费体力为3。接着，将新堆与原先的第三堆合并，又得到新的堆，数目为12，耗费体力为12。所以多多总共耗费体力=3+12=15。可以证明15为最小的体力耗费值。

输入描述 Input Description

    输入包括两行，第一行是一个整数n(1<＝n<=10000)，表示果子的种类数。第二行包含n个整数，用空格分隔，第i个整数ai(1<＝ai<=20000)是第i种果子的数目。

输出描述 Output Description

输出包括一行，这一行只包含一个整数，也就是最小的体力耗费值。输入数据保证这个值小于231。

样例输入 Sample Input

3
1 2 9

样例输出 Sample Output

15

数据范围及提示 Data Size & Hint

对于30％的数据，保证有n<=1000：
对于50％的数据，保证有n<=5000；
对于全部的数据，保证有n<=10000。

分析:

    刚开始拿到此题，心里一阵窃喜，这不就是最优二叉树的问题么？于是照着哈夫曼树的代码敲了一下，结果发现只有50分，后面的5个数据全部超时.

    代码如下:

const maxn=10000;
       max=2*maxn-1;
type
      node=record
         data:int64;
         prt,lch,rch:0..max;
        end;
     treetype=array[1..max]of node;
var tree:treetype;n,i:longint;s:int64;
procedure hufm(var tree:treetype);
var k,i,j:longint; 
 function min(h:integer):integer;
  var i,p:longint;m1:int64;
  begin
    m1:=9223372036854775807;
    for p:=1 to h do
     if (tree[p].prt=0)and(m1>tree[p].data) then
      begin
        i:=p;m1:=tree[p].data;
      end;
    min:=i;
  end;
begin
 fillchar(tree,sizeof(tree),0);
 for i:=1 to n do read(tree[i].data);
 for k:=n+1 to 2*n-1 do
  begin
    i:=min(k-1);tree[i].prt:=k;tree[k].lch:=i;
    j:=min(k-1);tree[j].prt:=k;tree[k].rch:=j;
    tree[k].data:=tree[i].data+tree[j].data;
  end;
end;
begin
  readln(n);
  hufm(tree);
  for i:=n+1 to 2*n-1 do
   s:=s+tree[i].data;
  writeln(s);
end.

    根据老师的建议,每次选出最小元素,与第二小的元素合并到一堆,这样每次都可以缩小范围,只需把每次合并耗费的体力值相加即可得到答案.

    程序用一个长度为10000的数组,每次找到最小的元素,把它和最后一个元素交换,然后范围缩小1,之后再次寻找最小的元素,两元素相加即可.

    代码如下:

var n,i,x,y,s:longint;
    a:array[1..10000]of longint;
procedure swap(var a,b:longint);
var t:longint;
begin
  t:=a;
  a:=b;
  b:=t;
end;
function min(n:longint):longint;
var i,p,q:longint;
begin
  p:=maxlongint;
  for i:=1 to n do
   if a[i]<p then
   begin
    p:=a[i];
    q:=i;
   end;
  min:=q;
end;
begin
  s:=0;
  readln(n);
  for i:=1 to n do
   read(a[i]);
  while n>1 do
  begin
   x:=min(n);swap(a[n],a[x]);dec(n);
   y:=min(n);a[y]:=a[y]+a[n+1];
   s:=s+a[y];
  end;
  writeln(s);
end.

相比第一种方法,效率提高了很多,10个数据全部通过,但相比之下,还是第三种方法效率高(老师想出来的,貌似运用的贪心算法),效率再次提高.

代码如下:

var a,b:array[1..10002]of longint;
    x,y,y1,n,i,s:longint;
procedure sort(l,r: longint);
var
i,j,x,y: longint;
begin
   i:=l;
   j:=r;
   x:=a[(l+r) div 2];
   repeat
      while a[i]<x do
        inc(i);
      while x<a[j] do
        dec(j);
      if not(i>j) then
         begin
            y:=a[i];a[i]:=a[j];a[j]:=y;
            inc(i);j:=j-1;
         end;
   until i>j;
   if l<j then
     sort(l,j);
   if i<r then
     sort(i,r);
end;
begin
    readln(n);
    s:=0;
    for i:=1 to 10002 do
     begin
      a[i]:=maxlongint;
      b[i]:=maxlongint;
     end;
    for i:=1 to n do
     read(a[i]);
    sort(1,n);
    x:=1;y:=1;y1:=1;
    while y1<n do
         if (a[x+1]<=b[y]) then begin b[y1]:=a[x]+a[x+1];inc(x,2); inc(y1);end
      else if a[x]>=b[y+1] then
        begin
         b[y1]:=b[y]+b[y+1];
         inc(y1);inc(y,2);
        end
       else
        begin
         b[y1]:=b[y]+a[x];
         inc(x);inc(y);inc(y1);
        end; 

    for i:=1 to n-1 do s:=s+b[i];
    writeln(s);
end.
本人也只是初学者,暂时能想到的就是这么多,貌似有可以使用优先队列的方法,有兴趣的读者可以百度或google一下看看.


联系
我们